在前期的文章中我们讲到了ESP8266的使用。不管是利用第三方平台还是自行搭建MQTT服务实现通信。各有优劣。但是想接入小爱，还是比较麻烦。

方案介绍

方案一 ：自建MQTT

通过自建MQTT服务器和ESP8266等设备建立连接。

优点： 安全可靠、数据在自己的服务器上。缺点： 需要自购服务器，并能保证服务器正常运行。无法与小爱等第三方平台直接连接，需要在HA中进行中转。

方案二 ：第三方服务

我们可以借助第三方服务，如阿里云、腾讯云、巴法云等。

优点： 无需购买服务器，只需上传代码即可。与第三方平台接入很简单。

缺点： 数据上传第三方服务器。

实验环境

• esp8266
• 继电器（选用）
• 巴法云

相关线路

使用

注册并登录巴法云，新建一个主题。

接下来，将密匙和订阅主题记录，并修改下面代码。

示例代码

/*
* 智能语言控制控制，支持同时天猫、小爱、小度、google Assistent控制
* 也同时支持web控制、小程序控制、app控制，定时控制等
* QQ群：566565915
* 项目示例：通过发送on或off控制开关
* 官网：bemfa.com
*/

#include <ESP8266WiFi.h>               //默认，加载WIFI头文件
#include "PubSubClient.h"              //默认，加载MQTT库文件

//********************需要修改的部分*******************//
const char* ssid = "逍遥子大表哥";           //修改，你的路由去WIFI名字
const char* password = "wifipassword@@";     //你的WIFI密码
#define ID_MQTT  "1e819b6a57*******ae395ed8"     //用户私钥，控制台获取
const char*  topic = "Led002";        //主题名字，可在巴法云控制台自行创建，名称随意
const int B_led = D2;       //单片机LED引脚值，D系列是NodeMcu引脚命名方式，其他esp8266型号将D2改为自己的引脚
//**************************************************//

const char* mqtt_server = "bemfa.com"; //默认，MQTT服务器
const int mqtt_server_port = 9501;      //默认，MQTT服务器
WiFiClient espClient;
PubSubClient client(espClient);

//灯光函数及引脚定义
void turnOnLed();
void turnOffLed();



void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Topic:");
  Serial.println(topic);
  String msg = "";
  for (int i = 0; i < length; i++) {
    msg += (char)payload[i];
  }
  Serial.print("Msg:");
  Serial.println(msg);
  if (msg == "on") {//如果接收字符on，亮灯
    turnOnLed();//开灯函数
  } else if (msg == "off") {//如果接收字符off，亮灯
    turnOffLed();//关灯函数
  }
  msg = "";
}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect
    if (client.connect(ID_MQTT)) {
      Serial.println("connected");
      Serial.print("subscribe:");
      Serial.println(topic);
      //订阅主题，如果需要订阅多个主题，可发送多条订阅指令client.subscribe(topic2);client.subscribe(topic3);
      client.subscribe(topic);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}


void setup() {
  pinMode(B_led, OUTPUT); //设置引脚为输出模式
  digitalWrite(B_led, HIGH);//默认引脚上电高电平
  Serial.begin(115200);     //设置波特率115200
  setup_wifi();           //设置wifi的函数，连接wifi
  client.setServer(mqtt_server, mqtt_server_port);//设置mqtt服务器
  client.setCallback(callback); //mqtt消息处理
  
}
void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

}

//打开灯泡
void turnOnLed() {
  Serial.println("turn on light");
  digitalWrite(B_led, LOW);
}
//关闭灯泡
void turnOffLed() {
  Serial.println("turn off light");
  digitalWrite(B_led, HIGH);
}

上传完成后，我们在控制台便可以看到设备上线了。

关于设备类型，由创建的主题名称决定：当主题名字后三位是001时为插座设备。当主题名字后三位是002时为灯泡设备。当主题名字后三位是003时为风扇设备。当主题名字后三位是004时为传感器设备。当主题名字后三位是005时为空调设备。

在本代码中主题为Led002，故为灯泡设备

绑定小爱

打开米家app，底部–我的—其他平台设备---->点击添加—>找打巴法，登录你的巴法云账号，如果巴法云控制台有创建设备，设备就会自动同步过去了。（如果没同步到，再次点击底部的同步设备即可）